Algoritmos y Programación a Nivel Profesional

Códigos resueltos en PSeInt.Site, Lenguaje C, C++, Python, DFD 1.0, JavaCript, Java NetBeas, Visual Studio, VBA
Curso de autocad para mac, Curso de C, certificacion google ads, curso marketing digital google, Curso de creación de páginas Web

DESARROLLAMOS TUS ALGORITMOS (+51)954263896

11. Desarrolle un algoritmo con arreglo bidimensionales para calcular lo siguiente:

1. Suma de las diagonales principales.
2. Promedio de la fila y columna escogida por el usuario final.
3. Determine el número mayor y menor de la matriz.
4. ¿Cuántas veces se repite un número dado?

PSeInt - FLEXIBLE DESCARGA CÓDIGO

    
Proceso www_PSeInt_Site
	
    Definir f, c, dato, opc, suma, s, may, men, repite como Entero;
    Dimension suma[4,4];

    Para f = 1 hasta 4 Con paso 1 Hacer
        Para c = 1 hasta 4 Con paso 1 Hacer
            suma[f,c] = azar(9);
        FinPara					
    FinPara	

    Escribir "DATOS DE LA MATRIZ";
    Para f = 1 hasta 4 Con paso 1 Hacer
        Para c = 1 hasta 4 Con paso 1 Hacer
            Escribir Sin Saltar suma[f,c], "  ";
        FinPara	
        Escribir " ";
    FinPara	
    Escribir " ";	
    Escribir "------------- TRABAJO CON MATRIZ ----------------";
    Escribir "1. Suma de las diagonales principales.";
    Escribir "2. Promedio de la fila y columna escogida por el usuario final.";
    Escribir "3. Daterminar el número mayor y menor de la matriz.";
    Escribir "4. ¿Cuántas veces se repite un número dado?";
    Escribir Sin Saltar "Opcion : ";
    Leer opc;
    Escribir " ";
		
    Segun (opc) Hacer
        1 :
            s = 0;								
            Para f = 1 hasta 4 Con paso 1 Hacer
                s = s + suma[f,f];			
            FinPara				
            Escribir "SUMA DIAGONAL 1 :",s;		
            s = 0;								
            Para f = 1 hasta 4 Con paso 1 Hacer
                s = s + suma[f,5-f];			
            FinPara				
            Escribir "SUMA DIAGONAL 2 :",s;	

    
    
        2 : 
            Escribir Sin Saltar "Eliga una fila o columna : [1 - 4]";
            Leer dato;
            Si (dato > 0 y dato <= 4) Entonces
                s = 0;
                Para f = 1 hasta 4 Con paso 1 Hacer	
                    s = s + suma[dato,f];
                FinPara	
                Escribir "PROMEDIO DE FILA : ", s/4;				
                s = 0;
                Para c = 1 hasta 4 Con paso 1 Hacer					
                    s = s + suma[c,dato];
                FinPara	
                Escribir "PROMEDIO DE COLUMNA : ", s/4;	
            SiNo
                Escribir "Error de ingreso...";
            FinSi						
        3: 	Para f = 1 hasta 4 Con paso 1 Hacer
                Para c = 1 hasta 4 Con paso 1 Hacer
                    Si (may < suma[f,c]) Entonces
                        may = suma[f,c];
                    FinSi									
                FinPara
            FinPara
            men = may;
            Para f = 1 hasta 4 Con paso 1 Hacer
                Para c = 1 hasta 4 Con paso 1 Hacer
                    Si (men > suma[f,c]) Entonces
                        men = suma[f,c];
                    FinSi									
                FinPara
            FinPara
            Escribir "MAYOR ES :", may;
            Escribir "MENOR ES :", men;			
        4 : Escribir Sin Saltar "Ingrese número : ";
            leer dato;
            Para f = 1 hasta 4 Con paso 1 Hacer
                Para c = 1 hasta 4 Con paso 1 Hacer
                    Si (dato == suma[f,c]) Entonces
                        repite = repite + 1;
                    FinSi
                FinPara
            FinPara
			
            Escribir "SE REPITE : ", repite, " VECES";
    FinSegun
	
FinProceso
    

PSeInt - ESTRICTO DESCARGA CÓDIGO

    
Proceso www_PSeInt_Site
	
    Definir f, c, dato, opc, suma, s, may, men, repite como Entero;
    Dimension suma[4,4];
	
    s <- 0;
    may <- 0;
    men <- 0;
    repite <- 0 ;
		
    Para f <- 0 hasta 3 Con paso 1 Hacer
        Para c <- 0 hasta 3 Con paso 1 Hacer
            suma[f,c] <- azar(9);
        FinPara					
    FinPara	
		
    Escribir "DATOS DE LA MATRIZ";
    Para f <- 0 hasta 3 Con paso 1 Hacer
        Para c <- 0 hasta 3 Con paso 1 Hacer
            Escribir Sin Saltar suma[f,c], "  ";
        FinPara	
        Escribir " ";
    FinPara	
    Escribir " ";	
    Escribir "------------- TRABAJO CON MATRIZ ----------------";
    Escribir "1. Suma de las diagonales principales.";
    Escribir "2. Promedio de la fila y columna escogida por el usuario final.";
    Escribir "3. Daterminar el número mayor y menor de la matriz.";
    Escribir "4. ¿Cuántas veces se repite un número dado?";
    Escribir Sin Saltar "Opcion : ";
    Leer opc;
	
    Escribir " ";
	
    Segun (opc) Hacer
        1 :
            s <- 0;								
            Para f <- 0 hasta 3 Con paso 1 Hacer
                s <- s + suma[f,f];			
            FinPara				
            Escribir "SUMA DIAGONAL 1 :",s;		
            s <- 0;								
            Para f <- 0 hasta 3 Con paso 1 Hacer
                s <- s + suma[f,3-f];			
            FinPara				
            Escribir "SUMA DIAGONAL 2 :",s;	
    
                
        2 : 
            Escribir Sin Saltar "Eliga una fila o columna : [1 - 4]";
            Leer dato;
            Si (dato >= 1 y dato <= 4) Entonces
                s <- 0;
                Para f <- 0 hasta 3 Con paso 1 Hacer	
                    s <- s + suma[dato-1,f];
                FinPara	
                Escribir "PROMEDIO DE FILA : ", s/4;				
                s <- 0;
                Para c <- 0 hasta 3 Con paso 1 Hacer					
                    s <- s + suma[c,dato-1];
                FinPara	
                Escribir "PROMEDIO DE COLUMNA : ", s/4;	
            SiNo
                Escribir "Error de ingreso...";
            FinSi			
        3: 	Para f <- 0 hasta 3 Con paso 1 Hacer
                Para c <- 0 hasta 3 Con paso 1 Hacer
                    Si (may < suma[f,c]) Entonces
                        may <- suma[f,c];
                    FinSi									
                FinPara
            FinPara
            men <- may;
            Para f <- 0 hasta 3 Con paso 1 Hacer
                Para c <- 0 hasta 3 Con paso 1 Hacer
                    Si (men > suma[f,c]) Entonces
                        men <- suma[f,c];
                    FinSi									
                FinPara
            FinPara
            Escribir "MAYOR ES :", may;
            Escribir "MENOR ES :", men;
        4 : Escribir Sin Saltar "Ingrese número : ";
            leer dato;
            Para f <- 0 hasta 3 Con paso 1 Hacer
                Para c <- 0 hasta 3 Con paso 1 Hacer
                    Si (dato == suma[f,c]) Entonces
                        repite <- repite + 1;
                    FinSi
                FinPara
            FinPara
			
            Escribir "SE REPITE : ", repite, " VECES";
    FinSegun
	
FinProceso
    



Aviso de Privacidad | Política de Cookies | Términos y condiciones

Derechos Reservados PSeInt.site