Algoritmos y Programación a Nivel Profesional

Códigos resueltos en PSeInt.Site, Lenguaje C, C++, Python, DFD 1.0, JavaCript, Java NetBeas, Visual Studio, VBA
Curso de autocad para mac, Curso de C, certificacion google ads, curso marketing digital google, Curso de creación de páginas Web

DESARROLLAMOS TUS ALGORITMOS (+51)954263896

12. Cajero automático

Hacer un programa que simule los procesos de un cajero automático, permitiendo que el usuario tenga tres intentos de ingreso, en caso de error se deberá bloquear la tarjeta. Si ingresa al sistema, el cajero deberá mostrar su saldo, permitir depósito y retiro de dinero; el programa deberá contar con 5 usuarios antes registrados.


DESCARGA CÓDIGOS

  PSeInt
  C - C++
  Python



PSeInt - ESTRICTO DESCARGA CÓDIGO

    
Algoritmo Cajero_Automatico
	
    Definir saldo, monto como Real;
    Definir f, contador, busca, opc, salir como Entero;
    Definir usuarios, clave como Caracter;
    Dimension saldo[5];
    Dimension usuarios[5];	//5 USUARIOS
		
    //SALDO	DEL CLIENTE
    saldo[0] <- 1000;
    saldo[1] <- 500;	
    saldo[2] <- 0;
    saldo[3] <- 2500;
    saldo[4] <- 1000;
	
    // CLAVES DE ACCESO
    usuarios[0] <- '5555';
    usuarios[1] <- '1111';
    usuarios[2] <- '8888';		
    usuarios[3] <- '3333';		
    usuarios[4] <- '2222';		
		
    contador <- 0;
    busca <- 0;
    opc <- 0;
    monto <- 0.0;
	
    Mientras (contador !=4 ) Hacer			
					
        Si (contador != 3 ) Entonces
			
            Escribir "***** CAJERO AUTOMÁTICO *****";
            Escribir "*                           *";
            Escribir "*       INTENTO NRO ", contador + 1, "       *";
            Escribir "*                           *";
            Escribir "*****************************";
            Escribir " ";
            Escribir Sin Saltar "CLAVE : ";
            Leer clave;
			
            Escribir "";
            
    
    
                
            Limpiar Pantalla;
			
            Para f <- 0 hasta 4 con paso 1 hacer				
                Si (clave == usuarios[f]) Entonces
                    busca <- f;
                    f <- 5;
                FinSi
            FinPara
			
            Si (busca != 0) Entonces
                salir <- 0;	
                Mientras (salir != 4) Hacer
                    Limpiar Pantalla;
                    Escribir "******************************";
                    Escribir "*                            *";
                    Escribir "*    BIENVENIDOS AL BANCO    *";
                    Escribir "*                            *";
                    Escribir "******************************";
                    Escribir "";
                    Escribir "MENU DE OPCIONES";
                    Escribir "1. VER SALDO";
                    Escribir "2. DEPOSITO";
                    Escribir "3. RETIRO";					
                    Escribir "4. SALIR";
                    Escribir "";
                    Escribir Sin Saltar "OPCIÓN : ";
                    Leer opc;
                    Escribir "";
    
    
                
                    Segun (opc) Hacer
                        1: 	Escribir "SALDO ACTUAL : ", saldo[busca]; 
                            Esperar Tecla;
							
                        2: 	Escribir Sin Saltar "MONTO A DEPOSITAR : ";
                            Leer monto;
                            saldo[busca] <- saldo[busca] + monto;
							
                        3: Escribir Sin Saltar "MONTO A RETIRAR : ";
                            Leer monto;
							
                            Si (monto > saldo[busca]) Entonces
                                Escribir "!Error no dispone de ese Saldo!..";
                                Esperar Tecla;
                            SiNo
                                saldo[busca] <- saldo[busca] - monto;	
                            FinSi

                        4: 	Escribir "Gracias por su vísita, regrese pronto...";
                            salir <- 4; 
                            contador <- 4;
                    FinSegun
                FinMientras
				
            SiNo
                contador <- contador + 1;
            FinSi
										
        SiNo			
            Escribir "*****************************";
            Escribir "*                           *";
            Escribir "*     TARJETA BLOQUEADA     *";
            Escribir "*                           * ";
            Escribir "*****************************";
            contador <- 4;
        FinSi	
		
    FinMientras
	
FinAlgoritmo
    


Aviso de Privacidad | Política de Cookies | Términos y condiciones

Derechos Reservados PSeInt.site